Datum i Excel

ExcelAtt behöva jobba med datum i Excel är inte jätteovanligt. Tråkigt nog saknas enkla funktioner för att exempelvis beräkna vilket veckonummer enligt europeisk stil (ISO 8601) ett datum har, hur många dagar det är i en månad eller när rörliga helgdagar infaller.

Mer om detta, samt lite fler tidshanteringstips i Excel, återfinner du nedan.

Behöver du infoga dagens datum eller klockslag i en cell? Ctrl+shift+, (d.v.s. ctrl+semikolon) ger dig aktuellt datum och ctrl+shift+. (d.v.s. ctrl+kolon) aktuell tid. Vill du istället ha ett datum som alltid är uppdaterat? Använd i så fall TODAY() eller den svenska motsvarigheten IDAG(), alternativt NOW() eller NU() om du behöver en fullständig tidsstämpel.

Lite formler för datumberäkningar då, som utlovat. Nedanstående exempel refererar till B1 för år och B2 för datum.

Excel A1:B2

Hur många dagar är det i den månad som datumet i B2 hör till?

=DAY(DATE(YEAR(B2);MONTH(B2)+1;0))

=DAG(DATUM(ÅR(B2);MÅNAD(B2)+1;0))

Veckor och helger då? Det finns funktioner för veckonummer i Excel, men de räknar inte på europeiskt manér, så en mer komplex lösning krävs. Påsk och dylika helger saknas också funktioner för att räkna ut när de inträffar. Försök att dissekera nedanstående formler görs på egen risk för hjärnblödning. Tro mig – de fungerar.

Aktuell vecka enligt ISO 8601

=INT((B2-DATE(YEAR(B2-WEEKDAY(B2-1)+4);1;3)+WEEKDAY(DATE(YEAR(B2-WEEKDAY(B2-1)+4);1;3))+5)/7)

=HELTAL((B2-DATUM(ÅR(B2-VECKODAG(B2-1)+4);1;3)+VECKODAG(DATUM(ÅR(B2-VECKODAG(B2-1)+4);1;3))+5)/7)

Datum för påskdagen

=FLOOR(DATE(B1;5;DAY(MINUTE(B1/38)/2+56));7)-34

=RUNDA.NER(DATUM(B1;5;DAG(MINUT(B1/38)/2+56));7)-34

Datum för midsommarafton

=DATE(B1;6;19+(7-WEEKDAY(DATE(B1;6;20))))

=DATUM(B1;6;19+(7-VECKODAG(DATUM(B1;6;20))))

Datum för alla helgons dag

=DATE(B1;10;31+(7-WEEKDAY(DATE(B1;10;31))))

=DATUM(B1;10;31+(7-VECKODAG(DATUM(B1;10;31))))

Annons:

Svara

E-postadressen publiceras inte. Obligatoriska fält är märkta *

Du kan använda följande HTML-taggar:

<a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <s> <strike> <strong>